rem ********************* AUTOEXEC.BAT ***********************************
@echo off
if "%config%"=="part1" goto pnf
call a:\bat\findl RAMDRIVE C D E F
goto suite1
:pnf
call a:\bat\findl RAMDRIVE D E F
:suite1
set temp=%RAMD%:\
set tmp=%RAMD%:\
path=%RAMD%:\;a:\;a:\dos;a:\bat
copy a:\command.com %RAMD%:\
set comspec=%RAMD%:\command.com
a:\dos\KEYB FR,,a:\dos\KEYBOARD.SYS
a:\dos\doskey

goto %config%

rem ************* DISQUE VIERGE - PARTITIONNEMENT ************************

:vierge
if not "%RAMD%"=="C" goto error0
call a:\bat\partit.bat
goto end


rem ************* RESTAURATION SANS FORMATAGE ****************************

:ecrase
if "%RAMD%"=="C" goto error1
if not %IOMEGA%*==* goto zipok1
call a:\bat\iomega.bat
:zipok1
call a:\bat\restau.bat
goto suite


rem ************* RESTAURATION AVEC FORMATAGE ****************************

:part1
if not "%RAMD%"=="D" goto error1
call a:\bat\formatag.bat
if not %IOMEGA%*==* goto zipok2
call a:\bat\iomega.bat
:zipok2
call a:\bat\restau.bat
goto suite


rem ************* DISQUE NON VIDE, FDISK A LA MAIN ***********************

:nonvide
cls
@echo ˙
@echo ˙       Je lance fdisk, a vous de nettoyer et de rebooter
@echo ˙       après avoir créé la partition de 1 Go
a:\dos\fdisk
goto suite


rem ************* PERSONNALISATION DU POSTE ******************************

:perso
if "%RAMD%"=="C" goto error1
a:\bat\perso.bat
goto fin


rem ************* sortie NE FAIT RIEN ************************************

:rien
if "%RAMD%"=="C" goto error1
cls
@echo ˙
@echo ˙
@echo ˙       Le programme est fini.
@echo ˙
@echo ˙       Pour le relancer, redémarrez le PC avec la disquette.
goto end


rem ************* FIN DE RESTAURATION, PROPOSITION DE PERSONNALISATION ***

:suite
@echo ˙
@echo ˙        Voulez vous passer à la personnalisation du poste (O/N) ?
choice /c:on /n
if ERRORLEVEL=2 goto end
if ERRORLEVEL=1 goto perso
goto end

rem ************* MESSAGES D'ERREURS *************************************

:error0
rem prompt $e[5m$p$e[5m$g$e[5m
cls
@echo ˙
@echo ˙                             ! Attention !
@echo ˙
@echo ˙               j'ai détecté une ou plusieurs partitions.
@echo ˙
@echo ˙               Redémarrez et choisissez une autre option.
@echo ˙
goto end

:error1
cls
@echo ˙
@echo ˙    Attention, je n'ai pas vu de partition, le ramdrive est en C: !
@echo ˙    Je relance le programme avec la bonne option :
@echo ˙
pause
set config=vierge
goto vierge

rem ************* FIN ****** *********************************************

:end